Trendfunktionen mit RGP für quadratische Funktionen

In Exceldiagrammen können verschiedene Trendfunktionen hinzugefügt werden. Unter anderem quadratische Gleichungen und Polynome höherer Ordnung. Auch die ermittelte Gleichung kann im Diagramm dargestellt werden. Wie bekomme ich aber die Parameter der Gleichung in meine Excel-Tabelle?

Mit der Funktion RGP können lineare Trends ermittelt werden. Allerdings ist diese Funktion wenig bekannt und wird noch seltener für quadratische Funktionen verwendet. Dies möchte ich heute ändern.

Beispiel 1: linearer Zusammenhang
Bei diesem Beispiel ist nur zu beachten, dass die Funktion RGP eine Matrixfunktion ist und mit Strg+Shift+Enter eingegeben werden muss. Damit die Parameter untereinander und nicht nebeneinander dargestellt werden habe ich noch die Funktion MTRANS verwendet.

A B C
5 Trendfunktion: y=mx+t
6 m 0,26733727
7 t 0,32652204
8
9
10 x y Trendfunktion
11 1 0,64608883 0,593859317
12 2 1,16693593 0,861196589
13 3 0,78049554 1,128533861
14 4 1,14535503 1,395871133
15 5 1,72425067 1,663208405
16 6 2,11008899 1,930545677

Formeln der Tabelle

C11   =$B$6*A11+$B$7
C12   =$B$6*A12+$B$7
C13   =$B$6*A13+$B$7
C14   =$B$6*A14+$B$7
C15   =$B$6*A15+$B$7
C16   =$B$6*A16+$B$7

Array-Formeln der Tabelle

B6:B7   {=MTRANS(RGP(B11:B16;A11:A16;WAHR;WAHR))}

Tabelle eingefügt mit Syntaxhighlighter 4.14

Beispiel 2: quadratischer Zusammenhang
Jetzt wird es schon etwas interessanter. Die Daten haben eine quadratischen Abhängigkeit. Um daraus eine lineare Gleichung zu erstellen wird eine Hilfsspalte benötigt. Diese Hilfspalte enthält die Werte "x²". Die Funktion RGP ist nun nicht nur von der Spalte A sondern von den beiden Spalten A und Spalte B abhängig.

A B C D
5 Trendfunktion: y=ax^2+bx+c
6 a 0,34075096
7 b 2,12326557
8 c -1,39796792
9
10 x x^2 y Trendfunktion
11 1 1 2,547813129 1,06604862
12 2 4 4,12437 4,21156709
13 3 9 2,911596613 8,03858749
14 4 16 13,63361996 12,5471098
15 5 25 23,88505227 17,7371341
16 6 36 20,10665539 23,6086603

Formeln der Tabelle

B11   =A11^2
B12   =A12^2
B13   =A13^2
B14   =A14^2
B15   =A15^2
B16   =A16^2
C11   =ZUFALLSZAHL()*A11^2+ZUFALLSZAHL()*A11+ZUFALLSZAHL()
C12   =ZUFALLSZAHL()*A12^2+ZUFALLSZAHL()*A12+ZUFALLSZAHL()
C13   =ZUFALLSZAHL()*A13^2+ZUFALLSZAHL()*A13+ZUFALLSZAHL()
C14   =ZUFALLSZAHL()*A14^2+ZUFALLSZAHL()*A14+ZUFALLSZAHL()
C15   =ZUFALLSZAHL()*A15^2+ZUFALLSZAHL()*A15+ZUFALLSZAHL()
C16   =ZUFALLSZAHL()*A16^2+ZUFALLSZAHL()*A16+ZUFALLSZAHL()
D11   =$B$6*A11^2+$B$7*A11+$B$8
D12   =$B$6*A12^2+$B$7*A12+$B$8
D13   =$B$6*A13^2+$B$7*A13+$B$8
D14   =$B$6*A14^2+$B$7*A14+$B$8
D15   =$B$6*A15^2+$B$7*A15+$B$8
D16   =$B$6*A16^2+$B$7*A16+$B$8

Array-Formeln der Tabelle

B6:B8   {=MTRANS(RGP(C11:C16;A11:B16;WAHR;WAHR))}

Tabelle eingefügt mit Syntaxhighlighter 4.14

Beispiel 3: Exponentieller Zusammenhang
Einige Leser werden es wohl schon ahnen. Mit dem Ansatz aus Beispiel 2 lassen sich viele weitere Trendfunktionen realisieren. In diesem Beispiel wird ein Exponentieller Zusammenhang dargestellt.

A B C D
5 Trendfunktion: y=aexp(x)+bx+c
6 a 0,84535327
7 b -9,79325382
8 c 17,2658044
9
10 x exp(x) y Trendfunktion
11 1 2,71828183 3,493569932 9,770459029
12 2 7,3890561 4,994322658 3,925659523
13 3 20,0855369 7,17553182 4,865417315
14 4 54,59815 48,68699444 24,24751393
15 5 148,413159 65,06157342 93,76108502
16 6 403,428793 306,7042748 299,5461322

Formeln der Tabelle

B11   =EXP(A11)
B12   =EXP(A12)
B13   =EXP(A13)
B14   =EXP(A14)
B15   =EXP(A15)
B16   =EXP(A16)
D11   =$B$6*EXP(A11)+$B$7*A11+$B$8
D12   =$B$6*EXP(A12)+$B$7*A12+$B$8
D13   =$B$6*EXP(A13)+$B$7*A13+$B$8
D14   =$B$6*EXP(A14)+$B$7*A14+$B$8
D15   =$B$6*EXP(A15)+$B$7*A15+$B$8
D16   =$B$6*EXP(A16)+$B$7*A16+$B$8

Array-Formeln der Tabelle

B6:B8   {=MTRANS(RGP(C11:C16;A11:B16;WAHR;WAHR))}

Tabelle eingefügt mit Syntaxhighlighter 4.14

Dem Artikel beigefügt ist eine Beispieldatei mit allen Beispielen.

Viel Spaß beim ausprobieren!

AnhangGröße
RGP für verschiedene Funktionen.xlsx19.18 KB
Your rating: Keine Average: 5 (9 votes)